[pawka-BWA]

#excel

Potrzebuję napisać makro które będzie kasować zawartość (tylko tekst) komórki w kolumnie A jeżeli komórka w B będzie pusta. Ma działać tak że jeśli skasuje zawartość B5 to A5 też zniknie.

Pomórzcie proszę bo bardzo tego potrzebuję

[brak_nicku]

@pawka-BWA:

Private Sub Worksheet_Change(ByVal Target As Range)
 If Not (Intersect(Target, Range("b5")) Is Nothing) Then
 If IsEmpty(Range("b5").Value) Then
 Application.EnableEvents = False
 Range("a5").Clear
 Application.EnableEvents = True
 End If
 End If
End Sub

[qusk]

@pawka-BWA: nie lepiej formuła w komórce AX =jeżeli(BX="", wartość, "")?

[pawka-BWA]

dzięki!

@brak_nicku:
A da się tak aby to działało nie tylko z raz? to działa przy zmianie na raz jednej komórki w B5 a gdy zmieniam wiecej to nie

[brak_nicku]

@pawka-BWA: nie rozumiem pytania, to działa bez względu na to, czy zmienia się jedną komórkę, czy na przykład kasuje zawartość całej kolumny na raz, pod warunkiem, że kasowana jest też zawartość B5

[pawka-BWA]

@brak_nicku: wiem ;) zaspany chyba byłem i już nie wiedziałem o co mi chodzi. W każdym razie chodziło mi o to żeby jeśli skasuje wartość z B5,B6 i tak dalej do B36 to skasuje się tez z A5,A6 i tak dalej do A36. B5 powiązane z A5, B6 powiązane z A6 i tak dalej. W B mam ilość wysłanych listów a w A daty i jeśli kasuję lub nie wpisuję nic

[brak_nicku]

@pawka-BWA:

Private Sub Worksheet_Change(ByVal Target As Range)
 Dim rColB As Range, rCell As Range

 Set rColB = Intersect(Target, Range("b5:b36"))
 If Not (rColB Is Nothing) Then
 On Error GoTo CleanExit
 Application.EnableEvents = False
 For Each rCell In rColB
 If IsEmpty(rCell) Then
 rCell.Offset(0, -1).Clear
 End If
 Next
 End If
CleanExit:
 Application.EnableEvents = True
End Sub

[pawka-BWA]

@brak_nicku: Dzięki! O to mi właśnie chodziło :)